42 lines
1.8 KiB
Nix
42 lines
1.8 KiB
Nix
# Test exclusions for the locally rebuilt x86-64-v3 package set.
|
|
#
|
|
# Selecting x86-64-v3 changes every affected derivation, so the normal
|
|
# nixpkgs binary cache cannot be used and upstream test suites run locally.
|
|
# The jeeves builder uses /tmp/nix-builds so filesystem tests run on tmpfs
|
|
# instead of ZFS with normalization=formD and utf8only=on; those tests remain
|
|
# enabled. The remaining workarounds cover UDP readiness and nested-worker
|
|
# scheduling races, plus architecture-dependent floating-point differences
|
|
# whose risk we accept for our workloads. Keep these exceptions visible until
|
|
# their causes are fixed.
|
|
_final: prev: {
|
|
gnutls = prev.gnutls.overrideAttrs (old: {
|
|
# This test uses a fixed four-second sleep instead of checking UDP
|
|
# readiness; the client saw no listener in the x86-64-v3 build.
|
|
postPatch = (old.postPatch or "") + ''
|
|
sed '2iexit 77' -i tests/serv-udp.sh
|
|
'';
|
|
});
|
|
|
|
pythonPackagesExtensions = prev.pythonPackagesExtensions ++ [
|
|
(_pythonFinal: pythonPrev: {
|
|
pytest-xdist = pythonPrev.pytest-xdist.overridePythonAttrs (old: {
|
|
# Its acceptance tests start nested worker pools. Limit the outer pool
|
|
# so deliberately crashing inner workers do not race under heavy load.
|
|
preCheck = builtins.replaceStrings [ "--numprocesses=$NIX_BUILD_CORES" ] [ "--numprocesses=8" ] (
|
|
old.preCheck or ""
|
|
);
|
|
});
|
|
|
|
scipy = pythonPrev.scipy.overridePythonAttrs (old: {
|
|
# x86-64-v3 FFT implementations produce rounding differences outside
|
|
# these tests' strict tolerances. We accept the numerical-precision
|
|
# risk for our workloads.
|
|
disabledTests = (old.disabledTests or [ ]) ++ [
|
|
"test_roundtrip_float32"
|
|
"test_roundtrip_scaling"
|
|
];
|
|
});
|
|
})
|
|
];
|
|
}
|