dotfiles/overlays/default.nix

{ inputs, ... }:
{
  # When applied, the stable nixpkgs set (declared in the flake inputs) will be accessible through 'pkgs.stable'
  stable = final: _prev: {
    stable = import inputs.nixpkgs-stable {
      system = final.stdenv.hostPlatform.system;
      config.allowUnfree = true;
    };
  };
  # When applied, the master nixpkgs set (declared in the flake inputs) will be accessible through 'pkgs.master'
  master = final: _prev: {
    master = import inputs.nixpkgs-master {
      system = final.stdenv.hostPlatform.system;
      config.allowUnfree = true;
    };
  };

  python-env = final: _prev: {
    my_python = final.python314.withPackages (
      ps:
      let
        bm25s = ps.buildPythonPackage rec {
          pname = "bm25s";
          version = "0.3.9";
          pyproject = true;

          src = final.fetchPypi {
            inherit pname version;
            hash = "sha256-iVxnnZUrfeg1XttfPhpiCh4vKU0dQrkZvwghzOLi9Zc=";
          };

          build-system = [ ps.setuptools ];
          dependencies = with ps; [
            numpy
            scipy
          ];

          pythonImportsCheck = [ "bm25s" ];
        };
      in
      with ps;
      [
        alembic
        apprise
        apscheduler
        beautifulsoup4
        ebooklib
        fastapi
        fastapi-cli
        httpx
        mypy
        numpy
        orjson
        pgvector
        polars
        psycopg
        pydantic
        pyfakefs
        pytest
        pytest-cov
        pytest-mock
        pytest-xdist
        python-multipart
        ruff
        scalene
        sqlalchemy
        sqlalchemy
        bm25s
        tenacity
        textual
        tiktoken
        tinytuya
        typer
        websockets
      ]
    );
  };
}